home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Apple II Magazines (DO)
/
Softdisk Magazette Volume 2, No. 07 (1983-03)(Softdisk)(Side B).zip
/
Softdisk Magazette Volume 2, No. 07 (1983-03)(Softdisk)(Side B).do
/
SPELLING UTILITY USE 1ST.bas
< prev
next >
Wrap
BASIC Source File
|
1996-12-24
|
6KB
|
191 lines
5 TEXT : HOME
10 D$ = CHR$(4)
20 DIM A$(100)
90 VTAB (10)
100 PRINT : PRINT "MYSTERY WORD SPELLING"
110 PRINT : PRINT : PRINT "BY DR. CHARLES E. OPHARDT
120 PRINT : PRINT "COPYRIGHT 1982."
125 PRINT : PRINT "PROGRAM MAY BE COPIED"
127 PRINT "BY SOFTDISK USERS."
130 FOR P = 1 TO 5000: NEXT P
140 HOME : PRINT
150 PRINT "YOU MAY ACCESS ANY OF THE FOLLOWING"
160 PRINT "PROGRAMS BY TYPING THE PROGRAM NUMBER."
170 PRINT : PRINT "1. MYSTERY WORD SPELLING."
180 PRINT : PRINT "2. GENERAL INSTRUCTIONS."
190 PRINT : PRINT "3. TYPE IN NEW SPELLING LISTS."
200 PRINT : PRINT "4. FAST VIEW ANY SPELLING LIST ON DISC."
210 PRINT : PRINT "5. CORRECT MISTAKES IN A SPELLING LIST."
220 PRINT : PRINT "6. SEE A DISC CATALOG."
230 PRINT : PRINT "7. QUIT THIS ENTIRE PROGRAM."
240 PRINT : INPUT "TYPE THE PROGRAM NUMBER YOU WANT ? ";P2
250 ON P2 GOTO 300,500,1000,3000,2000,400,280
260 PRINT : PRINT "TYPE A NUMBER 1-7.": GOTO 240
280 END
300 POKE 104,64: POKE 16384,0
305 PRINT CHR$(4);"RUN SPELLING"
400 PRINT D$;"CATALOG"
410 PRINT : INPUT "PRESS RETURN TO CONTINUE. ";X$
420 GOTO 140
500 HOME : PRINT
510 PRINT "GENERAL INSTRUCTIONS FOR MYSTERY WORD"
520 PRINT "SPELLING."
530 PRINT : PRINT "THIS SERIES OF PROGRAMS CAN BE USED"
540 PRINT "BY BOTH THE STUDENTS AND PARENTS OR"
541 PRINT "TEACHERS."
545 PRINT
550 PRINT "MYSTERY WORD SPELLING - THE MAIN"
560 PRINT "PROGRAM IS TO BE USED BY THE STUDENT"
570 PRINT "TO FIRST SLOWLY VIEW A SPELLING LIST"
580 PRINT "AND THEN THE WORDS ARE PRESENTED IN A"
590 PRINT "SYSTEMATIC MANNER SHOWING WITH BLANKS"
600 PRINT "THE NUMBER OF LETTERS IN A WORD."
602 PRINT : PRINT "LETTERS AND OTHER DRAWINGS ARE IN"
603 PRINT "HIGH RES. GRAPHICS. THE OBJECT IS TO"
604 PRINT "CORRECTLY SPELL THE WORD BEFORE A"
605 PRINT "LITTLE MAN IS DRAWN AND BREAKS THE ICE."
610 PRINT : PRINT "UP TO 7 MISSED LETTERS ARE ALLOWED"
620 PRINT "BEFORE A LITTLE MAN IS COMPLETED AND"
630 PRINT "BREAKS THE ICE."
640 PRINT : INPUT "PRESS RETURN TO CONTINUE.";X$
650 HOME : PRINT "THE TEACHER MAY USE A SERIES OF THREE"
655 PRINT "PROGRAMS TO TYPE IN NEW LISTS OF "
660 PRINT "SPELLING WORDS, QUICKLY VIEW ANY LIST"
670 PRINT "ON DISC, AND CORRECT ANY MISSPELLED"
680 PRINT "WORDS. THESE PROGRAMS ARE SELF"
690 PRINT "EXPLANATORY."
700 PRINT : INPUT "PRESS RETURN TO CONTINUE.";X$
710 GOTO 140
1000 REM MAKE TEXT
1020 D$ = CHR$(4): REM CTRL D
1030 HOME : TEXT
1035 I = 0
1040 PRINT "YOU GET TO TYPE ONE SPELLING WORD"
1050 PRINT "AT A TIME."
1060 PRINT : PRINT "EACH WORD MUST BE 10 LETTERS OR LESS."
1062 PRINT "DO NOT PUT ANY EXTRA SPACES IN FRONT"
1063 PRINT "OR IN BACK OF A WORD. DO NOT USE:"
1064 PRINT "COMMA, QUOTE, OR ANY NUMBER."
1065 PRINT "YOU MAY USE TWO WORDS WITH A BLANK"
1066 PRINT "IN THE MIDDLE OF THEM."
1070 PRINT : PRINT "THIS PROGRAM LETS YOU MAKE SPELLING"
1080 PRINT "LISTS OF UP TO 100 WORDS."
1090 PRINT :I = I +1
1100 PRINT "(PRESS THE RETURN KEY TO QUIT.)
1110 PRINT "TYPE WORD # ";I;": ";
1120 INPUT "";A$(I)
1130 C = LEN(A$(I))
1140 IF C >10 THEN PRINT "WORD HAS MORE THAN 10 LETTERS.": GOTO 1110
1150 IF A$(I) < >"" GOTO 1090
1160 PRINT
1170 INPUT "GIVE A NAME FOR THIS SPELLING LIST? ";N$
1180 PRINT D$;"OPEN ";N$
1190 PRINT D$"DELETE ";N$
1200 PRINT D$;"OPEN ";N$
1210 PRINT D$;"WRITE ";N$
1220 PRINT I -1
1230 FOR J = 1 TO I -1
1240 : PRINT A$(J)
1250 NEXT J
1260 PRINT D$;"CLOSE ";N$
1270 GOTO 140
2000 D$ = CHR$(4): REM CTRL D
2002 ONERR GOTO 2400
2003 I = 0
2005 HOME : PRINT
2010 PRINT "THIS PROGRAM LETS YOU CHECK A "
2020 PRINT "SPELLING LIST AND ALLOWS YOU TO MAKE"
2030 PRINT "CORRECTIONS."
2040 PRINT
2050 INPUT "NAME OF SPELLING LIST? ";Z$
2060 PRINT
2070 PRINT D$;"OPEN TEMP FILE"
2080 PRINT D$;"OPEN ";Z$
2090 PRINT D$;"READ ";Z$
2100 INPUT I
2105 IF I = 0 THEN 2400
2120 FOR J = 1 TO I
2130 : INPUT A$(J)
2140 NEXT J
2150 PRINT D$: FOR J = 1 TO I
2160 PRINT : PRINT "WORD # ";J;" ";A$(J)
2170 PRINT : INPUT "CHANGE THIS WORD (Y OR N) ? ";X$
2175 IF X$ = "N" THEN 2210
2180 IF X$ < >"Y" THEN 2170
2190 PRINT : PRINT "TYPE CORRECTED WORD? ";
2200 INPUT "";A$(J)
2205 IF LEN(A$(J)) >10 THEN PRINT "WORD OVER 10 LETTERS.": GOTO 2190
2210 NEXT J
2220 GOTO 2280
2230 PRINT D$;"CLOSE ";Z$
2240 PRINT D$;"CLOSE TEMP FILE"
2250 PRINT D$;"DELETE ";Z$
2260 PRINT D$;"RENAME TEMP FILE,";Z$
2270 GOTO 140
2280 PRINT D$;"WRITE TEMP FILE"
2290 PRINT I
2300 FOR J = 1 TO I
2310 : PRINT A$(J)
2320 NEXT J
2330 GOTO 2230
2400 REM ERROR ROUT.
2410 Y = PEEK(222)
2420 IF Y = 5 AND I = 0 THEN 2450
2425 IF Y = 255 THEN END
2430 PRINT "UNUSUAL ERROR ",Y: GOTO 2465
2450 PRINT "FILE NAME NOT FOUND."
2460 PRINT D$;"DELETE ";Z$
2465 PRINT D$;"DELETE TEMP FILE"
2470 PRINT : INPUT "DO YOU NEED TO SEE THE CATALOG (Y OR N)";X$
2480 IF X$ = "Y" THEN 2500
2490 IF X$ = "N" THEN 2040
2495 GOTO 2470
2500 PRINT D$;"CATALOG"
2510 PRINT : INPUT "PRESS RETURN TO CONTINUE.";X$
2520 GOTO 2040
3000 ONERR GOTO 3230
3002 I = 0:X = 0
3005 HOME : PRINT
3010 D$ = CHR$(4): REM CTRL D
3020 PRINT : PRINT "PROGRAM TO VIEW A SPELLING LIST"
3030 PRINT "CREATED BY THE MAKE SPELL LIST PROGRAM."
3040 PRINT
3050 INPUT "TYPE NAME OF SPELLING LIST? ";Z$
3060 PRINT
3070 PRINT D$;"OPEN ";Z$
3080 PRINT D$;"READ ";Z$
3090 INPUT I
3095 IF I = 0 THEN 3300
3110 FOR J = 1 TO I
3120 : INPUT A$(J)
3130 NEXT J
3140 PRINT D$;"CLOSE ";Z$
3150 FOR J = 1 TO I
3160 PRINT : PRINT "WORD # ";J;" ";A$(J)
3170 X = X +1
3180 IF X = 5 THEN 3210
3190 NEXT J
3200 PRINT "END OF LIST": GOTO 3390
3210 PRINT : INPUT "PRESS RETURN TO CONTINUE. ";X$
3220 X = 0: GOTO 3190
3230 REM ERROR ROUT
3240 Y = PEEK(222)
3245 IF Y = 5 AND I = 0 THEN 3300
3250 IF Y = 5 THEN 3400
3255 IF Y = 6 THEN 3300
3257 IF Y = 255 THEN END
3260 PRINT D$
3270 PRINT "UNUSUAL ERROR ";Y: END
3300 PRINT "FILE NAME NOT FOUND."
3305 PRINT D$;"DELETE ";Z$
3310 PRINT "NEED TO LOOK AT THE CATALOG?";
3320 INPUT " (Y OR N) ";X$
3330 IF X$ = "Y" THEN 3348
3340 IF X$ = "N" THEN 3040
3345 GOTO 3310
3348 PRINT D$;"CATALOG"
3350 PRINT : INPUT "PRESS RETURN TO CONTINUE.";X$
3355 GOTO 3040
3390 PRINT : INPUT "PRESS RETURN TO CONTINUE.";X$
3400 PRINT D$;"CLOSE ";Z$
3410 GOTO 140