home *** CD-ROM | disk | FTP | other *** search
/ Apple II Magazines (DO) / Softdisk Magazette Volume 2, No. 07 (1983-03)(Softdisk)(Side B).zip / Softdisk Magazette Volume 2, No. 07 (1983-03)(Softdisk)(Side B).do / SPELLING UTILITY USE 1ST.bas < prev    next >
BASIC Source File  |  1996-12-24  |  6KB  |  191 lines
  1. 5  TEXT : HOME 
  2. 10 D$ =  CHR$(4)
  3. 20  DIM A$(100)
  4. 90  VTAB (10)
  5. 100  PRINT : PRINT "MYSTERY WORD SPELLING"
  6. 110  PRINT : PRINT : PRINT "BY DR. CHARLES E. OPHARDT
  7. 120  PRINT : PRINT "COPYRIGHT 1982."
  8. 125  PRINT : PRINT "PROGRAM MAY BE COPIED"
  9. 127  PRINT "BY SOFTDISK USERS."
  10. 130  FOR P = 1 TO 5000: NEXT P
  11. 140  HOME : PRINT 
  12. 150  PRINT "YOU MAY ACCESS ANY OF THE FOLLOWING"
  13. 160  PRINT "PROGRAMS BY TYPING THE PROGRAM NUMBER."
  14. 170  PRINT : PRINT "1. MYSTERY WORD SPELLING."
  15. 180  PRINT : PRINT "2. GENERAL INSTRUCTIONS."
  16. 190  PRINT : PRINT "3. TYPE IN NEW SPELLING LISTS."
  17. 200  PRINT : PRINT "4. FAST VIEW ANY SPELLING LIST ON DISC."
  18. 210  PRINT : PRINT "5. CORRECT MISTAKES IN A SPELLING LIST."
  19. 220  PRINT : PRINT "6. SEE A DISC CATALOG."
  20. 230  PRINT : PRINT "7. QUIT THIS ENTIRE PROGRAM."
  21. 240  PRINT : INPUT "TYPE THE PROGRAM NUMBER YOU WANT ? ";P2
  22. 250  ON P2 GOTO 300,500,1000,3000,2000,400,280
  23. 260  PRINT : PRINT "TYPE A NUMBER 1-7.": GOTO 240
  24. 280  END 
  25. 300  POKE 104,64: POKE 16384,0
  26. 305  PRINT  CHR$(4);"RUN SPELLING"
  27. 400  PRINT D$;"CATALOG"
  28. 410  PRINT : INPUT "PRESS RETURN TO CONTINUE. ";X$
  29. 420  GOTO 140
  30. 500  HOME : PRINT 
  31. 510  PRINT "GENERAL INSTRUCTIONS FOR MYSTERY WORD"
  32. 520  PRINT "SPELLING."
  33. 530  PRINT : PRINT "THIS SERIES OF PROGRAMS CAN BE USED"
  34. 540  PRINT "BY BOTH THE STUDENTS AND PARENTS OR"
  35. 541  PRINT "TEACHERS."
  36. 545  PRINT 
  37. 550  PRINT "MYSTERY WORD SPELLING - THE MAIN"
  38. 560  PRINT "PROGRAM IS TO BE USED BY THE STUDENT"
  39. 570  PRINT "TO FIRST SLOWLY VIEW A SPELLING LIST"
  40. 580  PRINT "AND THEN THE WORDS ARE PRESENTED IN A"
  41. 590  PRINT "SYSTEMATIC MANNER SHOWING WITH BLANKS"
  42. 600  PRINT "THE NUMBER OF LETTERS IN A WORD."
  43. 602  PRINT : PRINT "LETTERS AND OTHER DRAWINGS ARE IN"
  44. 603  PRINT "HIGH RES. GRAPHICS. THE OBJECT IS TO"
  45. 604  PRINT "CORRECTLY SPELL THE WORD BEFORE A"
  46. 605  PRINT "LITTLE MAN IS DRAWN AND BREAKS THE ICE."
  47. 610  PRINT : PRINT "UP TO 7 MISSED LETTERS ARE ALLOWED"
  48. 620  PRINT "BEFORE A LITTLE MAN IS COMPLETED AND"
  49. 630  PRINT "BREAKS THE ICE."
  50. 640  PRINT : INPUT "PRESS RETURN TO CONTINUE.";X$
  51. 650  HOME : PRINT "THE TEACHER MAY USE A SERIES OF THREE"
  52. 655  PRINT "PROGRAMS TO TYPE IN NEW LISTS OF "
  53. 660  PRINT "SPELLING WORDS, QUICKLY VIEW ANY LIST"
  54. 670  PRINT "ON DISC, AND CORRECT ANY MISSPELLED"
  55. 680  PRINT "WORDS. THESE PROGRAMS ARE SELF"
  56. 690  PRINT "EXPLANATORY."
  57. 700  PRINT : INPUT "PRESS RETURN TO CONTINUE.";X$
  58. 710  GOTO 140
  59. 1000  REM   MAKE TEXT
  60. 1020 D$ =  CHR$(4): REM  CTRL D
  61. 1030  HOME : TEXT 
  62. 1035 I = 0
  63. 1040  PRINT "YOU GET TO TYPE ONE SPELLING WORD"
  64. 1050  PRINT "AT A TIME."
  65. 1060  PRINT : PRINT "EACH WORD MUST BE 10 LETTERS OR LESS."
  66. 1062  PRINT "DO NOT PUT ANY EXTRA SPACES IN FRONT"
  67. 1063  PRINT "OR IN BACK OF A WORD. DO NOT USE:"
  68. 1064  PRINT "COMMA, QUOTE, OR ANY NUMBER."
  69. 1065  PRINT "YOU MAY USE TWO WORDS WITH A BLANK"
  70. 1066  PRINT "IN THE MIDDLE OF THEM."
  71. 1070  PRINT : PRINT "THIS PROGRAM LETS YOU MAKE SPELLING"
  72. 1080  PRINT "LISTS OF UP TO 100 WORDS."
  73. 1090  PRINT :I = I +1
  74. 1100  PRINT "(PRESS THE RETURN KEY TO QUIT.)
  75. 1110  PRINT "TYPE WORD #  ";I;": ";
  76. 1120  INPUT "";A$(I)
  77. 1130 C =  LEN(A$(I))
  78. 1140  IF C >10  THEN  PRINT "WORD HAS MORE THAN 10 LETTERS.": GOTO 1110
  79. 1150  IF A$(I) < >"" GOTO 1090
  80. 1160  PRINT 
  81. 1170  INPUT "GIVE A NAME FOR THIS SPELLING LIST? ";N$
  82. 1180  PRINT D$;"OPEN ";N$
  83. 1190  PRINT D$"DELETE ";N$
  84. 1200  PRINT D$;"OPEN ";N$
  85. 1210  PRINT D$;"WRITE ";N$
  86. 1220  PRINT I -1
  87. 1230  FOR J = 1 TO I -1
  88. 1240 : PRINT A$(J)
  89. 1250  NEXT J
  90. 1260  PRINT D$;"CLOSE ";N$
  91. 1270  GOTO 140
  92. 2000 D$ =  CHR$(4): REM  CTRL D
  93. 2002  ONERR  GOTO 2400
  94. 2003 I = 0
  95. 2005  HOME : PRINT 
  96. 2010  PRINT "THIS PROGRAM LETS YOU CHECK A "
  97. 2020  PRINT "SPELLING LIST AND ALLOWS YOU TO MAKE"
  98. 2030  PRINT "CORRECTIONS."
  99. 2040  PRINT 
  100. 2050  INPUT "NAME OF SPELLING LIST? ";Z$
  101. 2060  PRINT 
  102. 2070  PRINT D$;"OPEN TEMP FILE"
  103. 2080  PRINT D$;"OPEN ";Z$
  104. 2090  PRINT D$;"READ ";Z$
  105. 2100  INPUT I
  106. 2105  IF I = 0  THEN 2400
  107. 2120  FOR J = 1 TO I
  108. 2130 : INPUT A$(J)
  109. 2140  NEXT J
  110. 2150  PRINT D$: FOR J = 1 TO I
  111. 2160  PRINT : PRINT "WORD # ";J;"  ";A$(J)
  112. 2170  PRINT : INPUT "CHANGE THIS WORD (Y OR N) ? ";X$
  113. 2175  IF X$ = "N"  THEN 2210
  114. 2180  IF X$ < >"Y"  THEN 2170
  115. 2190  PRINT : PRINT "TYPE CORRECTED WORD? ";
  116. 2200  INPUT "";A$(J)
  117. 2205  IF  LEN(A$(J)) >10  THEN  PRINT "WORD OVER 10 LETTERS.": GOTO 2190
  118. 2210  NEXT J
  119. 2220  GOTO 2280
  120. 2230  PRINT D$;"CLOSE ";Z$
  121. 2240  PRINT D$;"CLOSE TEMP FILE"
  122. 2250  PRINT D$;"DELETE ";Z$
  123. 2260  PRINT D$;"RENAME TEMP FILE,";Z$
  124. 2270  GOTO 140
  125. 2280  PRINT D$;"WRITE TEMP FILE"
  126. 2290  PRINT I
  127. 2300  FOR J = 1 TO I
  128. 2310 : PRINT A$(J)
  129. 2320  NEXT J
  130. 2330  GOTO 2230
  131. 2400  REM  ERROR ROUT.
  132. 2410 Y =  PEEK(222)
  133. 2420  IF Y = 5  AND I = 0  THEN 2450
  134. 2425  IF Y = 255  THEN  END 
  135. 2430  PRINT "UNUSUAL ERROR ",Y: GOTO 2465
  136. 2450  PRINT "FILE NAME NOT FOUND."
  137. 2460  PRINT D$;"DELETE ";Z$
  138. 2465  PRINT D$;"DELETE TEMP FILE"
  139. 2470  PRINT : INPUT "DO YOU NEED TO SEE THE CATALOG (Y OR N)";X$
  140. 2480  IF X$ = "Y"  THEN 2500
  141. 2490  IF X$ = "N"  THEN 2040
  142. 2495  GOTO 2470
  143. 2500  PRINT D$;"CATALOG"
  144. 2510  PRINT : INPUT "PRESS RETURN TO CONTINUE.";X$
  145. 2520  GOTO 2040
  146. 3000  ONERR  GOTO 3230
  147. 3002 I = 0:X = 0
  148. 3005  HOME : PRINT 
  149. 3010 D$ =  CHR$(4): REM  CTRL D
  150. 3020  PRINT : PRINT "PROGRAM TO VIEW A SPELLING LIST"
  151. 3030  PRINT "CREATED BY THE MAKE SPELL LIST PROGRAM."
  152. 3040  PRINT 
  153. 3050  INPUT "TYPE NAME OF SPELLING LIST? ";Z$
  154. 3060  PRINT 
  155. 3070  PRINT D$;"OPEN ";Z$
  156. 3080  PRINT D$;"READ ";Z$
  157. 3090  INPUT I
  158. 3095  IF I = 0  THEN 3300
  159. 3110  FOR J = 1 TO I
  160. 3120 : INPUT A$(J)
  161. 3130  NEXT J
  162. 3140  PRINT D$;"CLOSE ";Z$
  163. 3150  FOR J = 1 TO I
  164. 3160  PRINT : PRINT "WORD # ";J;"  ";A$(J)
  165. 3170 X = X +1
  166. 3180  IF X = 5  THEN 3210
  167. 3190  NEXT J
  168. 3200  PRINT "END OF LIST": GOTO 3390
  169. 3210  PRINT : INPUT "PRESS RETURN TO CONTINUE. ";X$
  170. 3220 X = 0: GOTO 3190
  171. 3230  REM  ERROR ROUT
  172. 3240 Y =  PEEK(222)
  173. 3245  IF Y = 5  AND I = 0  THEN 3300
  174. 3250  IF Y = 5  THEN 3400
  175. 3255  IF Y = 6  THEN 3300
  176. 3257  IF Y = 255  THEN  END 
  177. 3260  PRINT D$
  178. 3270  PRINT "UNUSUAL ERROR ";Y: END 
  179. 3300  PRINT "FILE NAME NOT FOUND."
  180. 3305  PRINT D$;"DELETE ";Z$
  181. 3310  PRINT "NEED TO LOOK AT THE CATALOG?";
  182. 3320  INPUT " (Y OR N) ";X$
  183. 3330  IF X$ = "Y"  THEN 3348
  184. 3340  IF X$ = "N"  THEN 3040
  185. 3345  GOTO 3310
  186. 3348  PRINT D$;"CATALOG"
  187. 3350  PRINT : INPUT "PRESS RETURN TO CONTINUE.";X$
  188. 3355  GOTO 3040
  189. 3390  PRINT : INPUT "PRESS RETURN TO CONTINUE.";X$
  190. 3400  PRINT D$;"CLOSE ";Z$
  191. 3410  GOTO 140